Login
Fix ProhibitPunctuationVars in tests.
[gknop/Perl-Critic.git] / xt / author / 93_version.t
1 #!perl -w
2
3 ##############################################################################
4 #      $URL$
5 #     $Date$
6 #   $Author$
7 # $Revision$
8 ##############################################################################
9
10 use strict;
11 use warnings;
12
13 use English qw< -no_match_vars >;
14 use Carp qw< confess >;
15
16 use File::Find;
17
18 use Test::More;
19
20 #-----------------------------------------------------------------------------
21
22 our $VERSION = '1.088';
23
24 #-----------------------------------------------------------------------------
25
26 plan 'no_plan';
27
28 my $last_version = undef;
29 find({wanted => \&check_version, no_chdir => 1}, 'blib');
30 if (! defined $last_version) {
31     fail('Failed to find any files with $VERSION');
32 }
33
34 sub check_version {
35     return if (! m{blib/script/}xms && ! m{\.pm \z}xms);
36
37     local $INPUT_RECORD_SEPARATOR = undef;
38     my $fh;
39     open $fh, '<', $_ or confess "$OS_ERROR";
40     my $content = <$fh>;
41     close $fh or confess "$OS_ERROR";
42
43     # Skip POD
44     $content =~ s/^__END__.*//xms;
45
46     # only look at perl scripts, not sh scripts
47     return if (m{blib/script/}xms && $content !~ m/\A \#![^\r\n]+?perl/xms);
48
49     my @version_lines = $content =~ m/ ( [^\n]* \$VERSION [^\n]* ) /gxms;
50     # Special cases for printing/documenting version numbers
51     @version_lines = grep {! m/(?:\\|\"|\'|C<|v)\$VERSION/xms} @version_lines;
52     @version_lines = grep {! m/^\s*\#/xms} @version_lines;
53     if (@version_lines == 0) {
54         fail($_);
55     }
56     for my $line (@version_lines) {
57         if (!defined $last_version) {
58             $last_version = shift @version_lines;
59             pass($_);
60         }
61         else {
62             is($line, $last_version, $_);
63         }
64     }
65
66     return;
67 }
68
69 # Local Variables:
70 #   mode: cperl
71 #   cperl-indent-level: 4
72 #   fill-column: 78
73 #   indent-tabs-mode: nil
74 #   c-indentation-style: bsd
75 # End:
76 # ex: set ts=8 sts=4 sw=4 tw=78 ft=perl expandtab shiftround :